2D旋转到3D旋转

我们知道2D旋转矩阵（参见julia语言的2D变换动画演示）的形式为

推广到3D维度，下式表示在3D的xy平面旋转θ角度，也可以称为绕z轴旋转θ角

3D的旋转比2D的旋转复杂得多，2D旋转只需要指定旋转角度就可以唯一确定旋转矩阵，在3D空间中不仅可以绕z轴旋转，也可以找x、y轴旋转，类似的我们可以列出yz平面（绕x轴）和zx平面（绕y轴）上相应的旋转矩阵为：

更一般地，3D旋转可以绕任意旋转轴旋转，而该旋转轴不一定与x、y、z轴的某一个重合，该如何表示这种旋转哪？

欧拉角

欧拉角是一种基于三种较简单旋转运动（称为俯仰、滚动和偏航）创建一般旋转的机制。如下图，一架沿x轴方向飞行的飞机可以通过转向左或转向右（偏航），朝上飞或朝下飞（俯仰），或简单绕x轴旋转（滚动）来改变飞行方向。

可以看出俯仰、偏航、滚动分别就是绕z轴、y轴、x轴旋转，上面已经给出了这三种特殊旋转的旋转矩阵。这三个矩阵的乘积就可以用来表示一般旋转，图形学中最常使用的定义顺序是将欧拉角表示为(φ, θ, ψ)（说明：φ：滚动角，θ：偏航角，ψ：俯仰角），那么3D空间一般旋转矩阵M就可以表示为三个旋转矩阵的积：

M = Ryz(ψ)Rzx(θ)Rxy(φ)

代入前面三个旋转矩阵表示如下，我们无需计算具体的结果，就表示为乘积的形式即可，在实际使用中乘积是通过计算机来完成的。这三种旋转是相互独立的，使用这个一般矩阵可以表示3D空间中的任意旋转。

3D一般旋转示例

如果你理解了欧拉角所表示的一般旋转的机制，你就可以编写程序来实现它。

下面的动画展示了欧拉角不断变换情况的一般旋转，实际上本文前面三个绕x、y、z轴的特殊旋转动画也是使用相同的旋转矩阵来实现的。

附上该动画实现的julia代码供参考：

# 引用Makie可视化库
using GLMakie
# 引用线性代数库
using LinearAlgebra

# 创建图像
fig = Figure()
# 在图像中创建子图
ax = Axis3(fig[1,1], aspect=(1,1,1), title="3D旋转示例", perspectiveness=0.25)
# 设置x、y、z轴坐标范围
limits!(ax, -1.2, 1.2, -1.2, 1.2, -1.2, 1.2)
# 该矩阵每一列表示为3D空间中的一个坐标点
# 这些坐标点用来绘制一个原点以及可旋转的坐标轴
oxyzuvw = [0 -1  0  0  2  0  0
           0  0 -1  0  0  2  0
           0  0  0 -1  0  0  2]  
# 俯仰角           
φ = Node(0.8)
# 偏航角
θ = Node(0.0)
# 滚动角
ψ = Node(1.2)
# yz平面旋转矩阵
Ryz = @lift([1 0 0
             0 cos($ψ) -sin($ψ)
             0 sin($ψ) cos($ψ)])
# zx平面旋转矩阵
Rzx = @lift([cos($θ) 0 sin($θ)
            0 1 0
            -sin($θ) 0 cos($θ)]) 
# xy平面旋转矩阵
Rxy = @lift([cos($φ) -sin($φ) 0
            sin($φ) cos($φ) 0
            0 0 1])
# Ryz(ψ)Rzx(θ)Rxy(φ)表示的一般旋转矩阵
M = @lift($Ryz*$Rzx*$Rxy)
# 计算旋转变换后的坐标序列
new_oxyzuvw = @lift($M*oxyzuvw)
# 取出旋转变换后的坐标原点
o_x,o_y,o_z = @lift([$new_oxyzuvw[1,1]]),@lift([$new_oxyzuvw[2,1]]),@lift([$new_oxyzuvw[3,1]])
# 取出旋转变换后的x、y、z、u、v、w序列，用来绘制带箭头的坐标轴
x = @lift($new_oxyzuvw[1,2:4])
u = @lift($new_oxyzuvw[1,5:7])
y = @lift($new_oxyzuvw[2,2:4])
v = @lift($new_oxyzuvw[2,5:7]) 
z = @lift($new_oxyzuvw[3,2:4])
w = @lift($new_oxyzuvw[3,5:7])
# 绘制坐标原点
meshscatter!(ax, o_x, o_y, o_z, color=:red, markersize=0.1)
# 绘制x、y、z三个坐标轴
arrows!(ax, x, z, y, u, w, v, label=["X","Y","Z"],
        color=[:blue, :red, :green])
# 文本标识出坐标轴
text!("X", position=@lift(($x[1], $z[1], $y[1])), color=:blue)
text!("Y", position=@lift(($x[2], $z[2], $y[2])), color=:red)
text!("Z", position=@lift(($x[3], $z[3], $y[3])), color=:green)
# 帧速
framerate = 30
# 为一迭代序列，范围为(-1/3π,1/3π)，每一帧的变化步长为1/framerate
timestamps = append!(collect(range(-1/3*pi, 1/3*pi, step=1/framerate)), 
                    collect(range(1/3*pi, -1/3*pi, step=-1/framerate)))
record(fig, "3d_rotate_一般轴.gif", timestamps; framerate = framerate) do t
    # t就是timestamps迭代序列中的值
    # 偏航
    θ[] = t
    # 俯仰
    φ[] = t
    # 滚动
    ψ[] = t
end